Viewing /PKGBUILD.

View raw.

Click here to go back to the Git tree for webext-localcdn-firefox.

# Maintainer: exponential <echo ZXhwb25lbnRpYWxtYXRyaXhAcHJvdG9ubWFpbC5jb20K | base64 -d>
# If your Firefox version doesn't support extracted webextentions
#_UNCOMPRESS=0
pkgname=webext-localcdn-firefox
_download_name="localcdn_fork_of_decentraleyes"
pkgver=2.6.67
_fileid=('4282737')
pkgrel=0
pkgdesc='Emulates remote frameworks and delivers them as local resource, extension for Firefox.'
arch=('all')
url='https://addons.mozilla.org/en-US/firefox/addon/localcdn-fork-of-decentraleyes/'
license=('MPL2')
optmakedepends=("unzip: to uncompress the webextention")
optdepends=('firefox' 'firefox-esr')
source=("https://addons.mozilla.org/firefox/downloads/file/$_fileid/localcdn_fork_of_decentraleyes-${pkgver}.xpi")
noextract=("${_download_name}-${pkgver}.xpi")
options=('!strip')
b2sums=('b2686c79622d343193f2dc420a570409c8bec226b0b36bdbe7e78b02b6b9bb7c62efc5e669c24225fcee4a04f4a6bd87b970362dde1308c44436ae2ecbe81fde')

prepare() {
 [ -z "$_UNCOMPRESS" ] && unzip -u "$_download_name-${pkgver}.xpi" -d "${srcdir}/$pkgname-${pkgver}" || :
}

package() {
  _mozilla_id="{ec8030f7-c20a-464f-9b0e-13a3a9e97384}"
  _ext_id="{b86e4813-687a-43e6-ab65-0bde4ab75758}"
  _license_path="/usr/share/common-licenses/MPL-2.0"

  install -dm755 "${pkgdir}/usr/share/mozilla/extensions/$_mozilla_id"
  if [ -z "$_UNCOMPRESS" ];
  then
    mv "${srcdir}/$pkgname-${pkgver}" "${pkgdir}/usr/share/mozilla/extensions/$_mozilla_id/$_ext_id"
  else
    install -Dm644 "$_download_name-${pkgver}.xpi" "${pkgdir}/usr/share/mozilla/extensions/$_mozilla_id/$_ext_id.xpi"
  fi
  # Doc
  install -dm755 "${pkgdir}/usr/share/doc/$pkgname"
  ln -s "$_license_path" "${pkgdir}/usr/share/doc/$pkgname/"
}